%Header Record
Format:TXT
Communication SW:0
Data Type:PG
Capacity:1748
File Name:GETDATA
Group Name:
Password:
Option1:
Option2:
Option3:
Option4:
%Data Record
\ClrText
" ":" ":" ":" ":" "
\Locate 1,1,"EA-100 Data Program"
\Locate 1,3,"Choose:"
\Locate 1,4,"1. New \Experiment"
\Locate 1,5,"2. \Download Data"
?\->C
C=2\=>\Goto9
\ClrText
" ":" ":" ":" "
\Locate 1,1,"Turn EA-100 unit on"
\Locate 1,2,"connect probe(s)"
\Locate 1,3,"\and then press EXE"\Disp\Locate 1,5,"Initialising..."
\ClrList
{0}\->\List 1
\Send(\List 1)
\ClrText
" ":" "
\Locate 1,1,"Number of samples"
\Locate 11,2,"(2 - 250)"
?\->N
N<2\=>2\->N
N>250\=>250\->N
\ClrText
" ":" "
\Locate 1,1,"Time between samples"
\Locate 6,2,"(.001s - 16000s)"
?\->T
T<.001\=>.001\->T
T>16000\=>16000\->T
" ":" "
\Locate 1,6,"Total time (s)="
\Locate 16,6,NT\Disp\ClrText
" ":" "
\Locate 1,1,"Checking mem\ory..."
{7}\->\List 1
\Send(\List 1)
\Receive(\List 1)
\Dim \List 1-6\->P
\Seq(0,I,1,N,1)\->\List 1
\List 1\->\List 2
P=1\=>\Goto1
\List 1\->\List 3
P=2\=>\Goto1
\List 1\->\List 4
\Lbl 1
\Locate 10,2,"mem\ory OK"\Disp" ":" ":" "
\Locate 1,4,"Press EXE to start"
\Locate 1,5,"data sampling"\Disp{3,T,N,2,0}\->\List 1
\Send(\List 1)
\ClrText
" ":" ":" "
\Locate 1,1,"Sampling in progress"
\Locate 1,2,"Wait until DONE"
\Locate 1,3,"appears on EA-100."
\Goto8
\Lbl 9
\ClrText
" ":" ":" "
\Locate 1,1,"Check EA-100 is on"
\Locate 1,2,"with probes still"
\Locate 1,3,"connected"
\Lbl 8
" "
\Locate 1,4,"\Then press EXE..."\Disp\ClrText
\Locate 1,1,"R\Receiving data"
"Time....."
\Receive(\List 1)
\Dim \List 1\->N
\If C=2
\Then 3\->V
\List 1[2]\->T
\List 1[1]>1\EE\(-)4\=>2\->V
\Int (T*10^(V+1))\->T
\Int (T/10)\->W
T-10W\>=5\=>W+1\->W
W/10^V\->T
{7}\->\List 1
\Send(\List 1)
\Receive(\List 1)
\Dim \List 1-6\->P
\IfEnd
\Seq(I,I,0,T(N-1),T)\->\List 1
"Data 1..."
\Receive(\List 2)
2-\Int \log \Abs \Max(\List 2)\->R
R>2\=>2\->R
R<0\=>0\->R
\Int (10^R*\List 2+.5)/10^R\->\List 2
\Max(\List 2)-\Min(\List 2)\->M
P=1\=>\Goto2
"Data 2..."
\Receive(\List 3)
2-\Int \log \Abs \Max(\List 3)\->R
R>2\=>2\->R
R<0\=>0\->R
\Int (10^R*\List 3+.5)/10^R\->\List 3
\Max(\List 3)-\Min(\List 3)+M\->M
P=2\=>\Goto2
"Data 3..."
\Receive(\List 4)
2-\Int \log \Abs \Max(\List 4)\->R
R>2\=>2\->R
R<0\=>0\->R
\Int (10^R*\List 4+.5)/10^R\->\List 4
\Max(\List 4)-\Min(\List 4)+M\->M
\Lbl 2
N=1\ Or M=0\=>\Goto4
\ClrText
" ":" "
\Locate 1,1,"All data in"
\Locate 1,2,"EXE to graph..."\Disp\ClrGraph
\S-WindAuto
\S-Gph1 \DrawOn,\Scatter,\List1,\List2,1,\Cross
\S-Gph2 \DrawOff
\S-Gph3 \DrawOff
P=1\=>\Goto3
\S-Gph2 \DrawOn,\Scatter,\List1,\List3,1,\Square
P=2\=>\Goto3
\S-Gph3 \DrawOn,\Scatter,\List1,\List4,1,\Dot
\Lbl 3
10T\->\Xscl
100\->\Yscl
\DrawStat
\Text 2,90,"DONE"
\Text 8,90,"EXE TO"
\Text 14,90,"CONTINUE"\Disp\Lbl 4
\ClrText
" "
\Locate 1,1,"Finished"
\Locate 1,2,"Again...... EXE"
\Locate 1,3,"See data... MENU,2"
\Locate 1,4,"End........ AC\slashON"
%End
%Header Record
Format:TXT
Communication SW:0
Data Type:PG
Capacity:9904
File Name:GETDATA2
Group Name:
Password:
Option1:NL
Option2:
Option3:
Option4:
%Data Record
0\->A~Z
\If \theta=94054777:\Then 0\->\theta:\Dim \Mat Z:\List \Ans[1]=5\ And \List \Ans[2]=5\=>94054777\->\theta:\IfEnd
\If \theta\<>94054777:\Then \Identity 5\->\Mat Z:\Fill(0,\Mat Z):15\->N:2\->T:1\->R:N\->\Mat Z[1,1]:T\->\Mat Z[1,2]:R\->\Mat Z[1,3]:1\->\Mat Z[2,1]:1\->\Mat Z[3,1]:\Else \Mat Z[1,1]\->N:\Mat Z[1,2]\->T:\Mat Z[1,3]\->R:\Mat Z[1,5]\->M:\Mat Z[2,5]\->O:\Mat Z[3,5]\->U:\IfEnd
94054777\->\theta
\Do
\BG-None:\ClrText:\Cls:\ViewWindow 1,127,0,63,1,0
\Text 1,1,"EA-100 Communication Center"
\Text 13,1,"Channels:":\Text 13,40,"CH1":\Text 13,61,"CH2":\Text 13,82,"CH3":\Text 13,103,"Sonic":\Text 19,1,"Probes:":\Text 25,1,"Samples:":\Text 31,1,"Interval:":\Text 37,1,"Tot time:":\Text 43,1,"Rec Time:"
2\->L:\Goto1:\Lbl 2
\For 2\->I \To 107 \Step 21:\Green \F-Line I,63,I,56:\Green \F-Line I,56,I+18,56:\Next 
\Do
\Orange \Text 50,1,"                               "
\Green \Text 58,4," Go ":\Green \Text 58,25,"Get ":\Green \Text 58,46,"SetS":\Green \Text 58,67,"SetP":\Green \Text 58,88,"Help":\Green \Text 58,109,"Exit ":\PxlOn 1,1
\Do:8-\Int (\Getkey/10)\->K:\LpWhile K=8
4\->P:\For 1\->I \To 4:\Mat Z[2,I]=0\=>\Dsz P:P\->Q:\Next :R\=>\Isz Q
\If K=1:\Then \Orange \Text 50,1,"Wait! Checking mem\ory..":\ClrList
\Green \Text 58,4,"   ":\Green \Text 58,25,"   ":\Green \Text 58,46,"    ":\Green \Text 58,67,"    ":\Green \Text 58,88,"    ":\Green \Text 58,109,"    ":\PxlOn 1,1
\Seq(0,I,1,N,1)\->\List 1:Q\>=2\=>\List 1\->\List 2:Q\>=3\=>\List 1\->\List 3:Q\>=4\=>\List 1\->\List 4:Q\>=5\=>\List 1\->\List 5
0\->S
\If R=0\ And T\>=1.8\ And P=2:\Then 1.52\->H:2\->S:\IfEnd
\If R=1:\Then \If P=1\ And T\>=1.2:\Then 1\->S:0.97\->H:\IfEnd:\If P=2\ And T\>=1.8:\Then 1\->S:1.59\->H:\IfEnd:\If P=3\ And T\>=2.5:\Then 1\->S:2.22\->H:\IfEnd:\IfEnd
M=7\=>0\->S
\If S:\Then \Orange \Text 50,1,"Display plot real-time?  "
\Green \Text 58,4,"Yes":\Green \Text 58,25,"No":\PxlOn 1,1
\Do:8-\Int (\Getkey/10)\->I:\LpWhile I=8:I=2\=>0\->S
\If S:\Then 1\->D:N\->E:\ClrText:" ":\Locate 1,1,"\Vertical graph scl":" ":S=2\=>\Locate 1,2,"(highest Ch probe)":" ":\Locate 1,3,"\Ymin \-> \Ymax":"\Ymin"?\->F:"\Ymax"?\->G
\If S=2:\Then \ClrText:" ":\Locate 1,1,"\Horizontal graph scl":" ":\Locate 1,2,"\Xmin \-> \Xmax":"\Xmin"?\->D:"\Xmax"?\->E:\IfEnd:\IfEnd
\IfEnd
\Orange \Text 50,1,"Wait! Initialising EA100..":\Green \Text 58,4,"    ":\Green \Text 58,25,"    ":\PxlOn 1,1
{0}\->\List 6:\Send(\List 6)
\For 1\->I \To 4:\If \Mat Z[2,I]:\Then {1,I,1}\->\List 6:\Send(\List 6):\Mat Z[3,I]\->A:\Mat Z[4,I]\->B:{4,I,1,0,B,A}\->\List 6:\Send(\List 6):\IfEnd:\Next 
\If S:\Then {3,T-H,1,0,0}\->\List 6:\Send(\List 6):{8}\->\List 6:\IfEnd
S=1\=>\Seq(TX,X,0,N-1,1)\->\List 1
\Orange \Text 50,1,"All OK. F1 to start sampling"
\Green \Text 58,4," Go ":\PxlOn 1,1
\Do:8-\Int (\Getkey/10)\->I:\LpWhile I\<>1
\If S:\Then \ViewWindow D,E,1,F,G,1:\AxesOff:\Cls:\F-Line D,F,D,G:\F-Line D,F,E,F:\Text 1,82,"Sample 1"
\If S=1:\Then \Send(\List 6):\Receive(V):V\->\List 2[1]:\If P\>=2:\Then \Receive(V):V\->\List 3[1]:\IfEnd:\If P=3:\Then \Receive(V):V\->\List 4[1]:\IfEnd
\For 2\->I \To N:\Send(\List 6):\Text 1,111,I:\Receive(V):\Blue \F-Line I-1,\List 2[I-1],I,V:V\->\List 2[I]
\If P\>=2:\Then \Receive(V):V\->\List 3[I]:\Orange \F-Line I-1,\List 3[I-1],I,V:\IfEnd
\If P=3:\Then \Receive(V):V\->\List 4[I]:\Green \F-Line I-1,\List 4[I-1],I,V:\IfEnd
\Next :\IfEnd
\If S=2:\Then \For 1\->I \To N:\Send(\List 6):\Text 1,111,I:\Receive(V):V\->\List 1[I]:\Receive(V):V\->\List 2[I]:\PlotOn \List 1[I],\List 2[I]:\Next :\IfEnd
{0}\->\List 6
\Text 22,90,"EXE to":\Text 28,90,"continue"\Disp\AxesOn
\Else {3,T,N,R,M,O,U}\->\List 6:\Send(\List 6)
\Orange \Text 50,1,"Sampling.. When DONE press F1"
\Green \Text 58,4," F1 ":\Green \Text 58,88,"Halt":\Green \Text 58,109,"Quit":\PxlOn 1,1
\Do:8-\Int (\Getkey/10)\->I:\LpWhile I=8
\If I=5:\Then \Orange \Text 50,1,"Press HALT on EA100, then OK  ":\Green \Text 58,4,"    ":\Green \Text 58,88,"    ":\Green \Text 58,109," OK ":\PxlOn 1,1
\Do:8-\Int (\Getkey/10)\->I:\LpWhile I=8:{0}\->\List 6:\Send(\List 6):5\->I:\IfEnd
\If I=1:\Then 2\->K:\IfEnd
\IfEnd:\IfEnd
\If K=2:\Then \Orange \Text 50,1,"Wait.. Data\->\List              ":0\->I:1\->W
\Green \Text 58,4,"    ":\Green \Text 58,25,"    ":\Green \Text 58,46,"    ":\Green \Text 58,67,"    ":\Green \Text 58,88,"    ":\Green \Text 58,109,"    ":\PxlOn 1,1
\If Q\>=1:\Then \For 1\->H \To Q:\Orange \Text 50,68,H:\PxlOn 1,1:\For 4\->J \To W \Step \(-)1:\Mat Z[2,J]\=>J\->I:\Next :H=1\ And R\=>6\->I:{5,I}\->\List 6:\Send(\List 6)
H=1\=>\Receive(\List 1):H=2\=>\Receive(\List 2):H=3\=>\Receive(\List 3):H=4\=>\Receive(\List 4):H=5\=>\Receive(\List 5):I+1\->W:H=1\ And R\=>1\->W:\Next 
\IfEnd
\Orange \Text 50,1,"All data in: Round?"
\Green \Text 58,4,"Yes ":\Green \Text 58,25," No ":\PxlOn 1,1
\Do:8-\Int (\Getkey/10)\->I:\LpWhile I=8
\If I=1:\Then \Orange \Text 50,1,"Wait...                 "
\If Q\>=1:\Then 2-\Int \log \Abs \Max(\List 1)\->J:J>2\=>2\->J:J<0\=>0\->J:\Int (10^J*\List 1+.5)/10^J\->\List 1:\IfEnd
\If Q\>=2:\Then 2-\Int \log \Abs \Max(\List 2)\->J:J>2\=>2\->J:J<0\=>0\->J:\Int (10^J*\List 2+.5)/10^J\->\List 2:\IfEnd
\If Q\>=3:\Then 2-\Int \log \Abs \Max(\List 3)\->J:J>2\=>2\->J:J<0\=>0\->J:\Int (10^J*\List 3+.5)/10^J\->\List 3:\IfEnd
\If Q\>=4:\Then 2-\Int \log \Abs \Max(\List 4)\->J:J>2\=>2\->J:J<0\=>0\->J:\Int (10^J*\List 4+.5)/10^J\->\List 4:\IfEnd
\If Q\>=5:\Then 2-\Int \log \Abs \Max(\List 5)\->J:J>2\=>2\->J:J<0\=>0\->J:\Int (10^J*\List 5+.5)/10^J\->\List 5:\IfEnd
\IfEnd
0\->I:\If Q\>=2\ And (\Max(\List 1)-\Min(\List 1))\ And R\<>2:\Then \If R:\Then \Orange \Text 50,1,"\Graph Time v data? ":\Else \Orange \Text 50,1,"\Graph Probe1 v Probe2 ?":\IfEnd
\Green \Text 58,4,"Scat":\Green \Text 58,25,"\Line":\Green \Text 58,46," No ":\PxlOn 1,1
\Do:8-\Int (\Getkey/10)\->I:\LpWhile I=8:\IfEnd
\If I=1\ Or I=2:\Then \ClrGraph:\S-WindAuto:\AxesOn:\S-Gph1 \DrawOff:\S-Gph2 \DrawOff:\S-Gph3 \DrawOff:10\Mat Z[1,2]\->\Xscl:100\->\Yscl
\If Q\>=2:\Then I=1\=>\S-Gph1 \DrawOn,\Scatter,\List1,\List2,1,\Cross,\Blue :I=2\=>\S-Gph1 \DrawOn,\xyLine,\List1,\List2,1,\Dot,\Blue :\DrawStat:\IfEnd
\If Q\>=3:\Then \StoPict 1:\Cls:\BG-Pict 1:\AxesOff:I=1\=>\S-Gph1 \DrawOn,\Scatter,\List1,\List3,1,\Square,\Blue :I=2\=>\S-Gph1 \DrawOn,\xyLine,\List1,\List3,1,\Cross,\Blue :\DrawStat:\IfEnd
\If Q\>=4:\Then \StoPict 1:\Cls:\BG-Pict 1:\AxesOff:I=1\=>\S-Gph1 \DrawOn,\Scatter,\List1,\List4,1,\Cross,\Orange :I=2\=>\S-Gph1 \DrawOn,\xyLine,\List1,\List4,1,\Square,\Orange :\DrawStat:\IfEnd
\If Q\>=5:\Then \StoPict 1:\Cls:\BG-Pict 1:\AxesOff:I=1\=>\S-Gph1 \DrawOn,\Scatter,\List1,\List5,1,\Square,\Orange :I=2\=>\S-Gph1 \DrawOn,\Scatter,\List1,\List5,1,\Dot,\Orange :\DrawStat:\IfEnd
\Text 22,90,"EXE to":\Text 28,90,"continue"\Disp\BG-None:\AxesOn:\IfEnd
\IfEnd
\If K=3:\Then \Do:\Orange \Text 50,1,"SETUP SAMPLING    "
\Green \Text 58,4,"Rset":\Green \Text 58,25,"Smpl":\Green \Text 58,46,"Intv":\Green \Text 58,67,"RecT":\Green \Text 58,88,"Help":\Green \Text 58,109,"\Done":\PxlOn 1,1
\Do:8-\Int (\Getkey/10)\->J:\LpWhile J=8
\If J=1:\Then \Orange \Text 50,1,"Resetting..    ":\PxlOn 1,1:\Fill(0,\Mat Z):15\->N:2\->T:1\->R:0\->M:M\->\Mat Z[1,5]:N\->\Mat Z[1,1]:T\->\Mat Z[1,2]:R\->\Mat Z[1,3]:1\->\Mat Z[2,1]:1\->\Mat Z[3,1]:4\->L:\Goto1:\Lbl 4:\IfEnd
\If J=2:\Then \ClrText:" ":\Locate 1,1,"Number of samples":" ":\Locate 1,2,"Type number, then EXE":" ":\Locate 1,3,"[1 to 255]":?\->N:N\->\Mat Z[1,1]:5\->L:\Goto8:\Lbl 5:\IfEnd
\If J=3:\Then \ClrText:" ":\Locate 1,1,"Time (seconds)":" ":\Locate 1,2,"between samples":" ":\Locate 1,3,"Type number, then EXE":" ":\Locate 1,4,"[.001 to 16000]":?\->T:T\->\Mat Z[1,2]:6\->L:\Goto8:\Lbl 6:\IfEnd
\If J=4:\Then \PxlOff 62,41:\Orange \Text 50,1,"Rec Time option?"
\Do:\Green \Text 58,4,"Off ":\Green \Text 58,25,"\Abs ":\Green \Text 58,46,"Rel ":\Green \Text 58,67,"    ":\Green \Text 58,88,"Help":\Green \Text 58,109,"    ":\PxlOn 1,1:\Do:7-\Int (\Getkey/10)\->H:\LpWhile H=7
\If H=1\ Or H=2\ Or H=0:\Then H\->R:R\->\Mat Z[1,3]:7\->L:\Goto9:\Lbl 7:\IfEnd
\If H=4:\Then \StoPict 1:\Cls
\Text 1,1,"HELP":\Text 7,1,"Rec\ord time options are..":\Text 19,1,"F1 Off - time not rec\orded":\Text 25,1,"F2 Absolute, sequential time":\Text 31,1,"F3 Relative, time intervals"
107\->I:\Green \F-Line I,63,I,56:\Green \F-Line I,56,I+18,56:\Green \Text 58,109," OK":\PxlOn 1,1:\Do:8-\Int (\Getkey/10)\->I:\LpWhile I\<>6:\Cls:\RclPict 1:\IfEnd
\LpWhile H=4:\IfEnd
\If J=5:\Then \StoPict 1:\Cls:\Text 1,1,"HELP":\Text 7,1,"Sampling options are..":\Text 19,1,"F1 Reset all":\Text 25,1,"F2 Set number of samples"
\Text 31,1,"F3 Set time between samples":\Text 37,1,"F4 Rec\ord time options":\Text 43,1,"F6 \Return to main menu"
107\->I:\Green \F-Line I,63,I,56:\Green \F-Line I,56,I+18,56:\Green \Text 58,109," OK":\PxlOn 1,1:\Do:8-\Int (\Getkey/10)\->H:\LpWhile H\<>6:\Cls
\Text 1,1,"HELP":\Text 7,1,"Real-time graph options when:":\Text 19,1,"Probes RecTime Interval":\Text 25,1,"  1     \Abs     \>=1.2 s":\Text 31,1,"  2     \Abs     \>=1.8 s"
\Text 37,1,"  2     Off     \>=1.8 s":\Text 43,1,"  3     \Abs     \>=2.5 s":107\->I:\Green \F-Line I,63,I,56:\Green \F-Line I,56,I+18,56:\Green \Text 58,109," OK":\PxlOn 1,1:\Do:8-\Int (\Getkey/10)\->H:\LpWhile H\<>6:\Cls:\RclPict 1:\IfEnd
\LpWhile J\<>6
\PxlOff 62,41
\IfEnd
\If K=4:\Then \Do:\Orange \Text 50,1,"PROBE SETUP Choose channel"
\Green \Text 58,4,"CH1 ":\Green \Text 58,25,"CH2 ":\Green \Text 58,46,"CH3 ":\Green \Text 58,67,"SONC":\Green \Text 58,88,"    ":\Green \Text 58,109,"\Done":\PxlOn 1,1
\Do:8-\Int (\Getkey/10)\->C:\LpWhile C=8
\If C<5:\Then C=1\=>\Orange \Text 50,50,"Use CH1?      ":C=2\=>\Orange \Text 50,50,"Use CH2?      ":C=3\=>\Orange \Text 50,50,"Use CH3?      ":C=4\=>\Orange \Text 50,50,"Use SONIC?     "
\Green \Text 58,4,"Yes ":\Green \Text 58,25,"No  ":\Green \Text 58,46,"   ":\Green \Text 58,67,"    ":\Green \Text 58,109,"    ":\PxlOn 1,1
\Do:8-\Int (\Getkey/10)\->H:\LpWhile H=8
\If H=2:\Then 0\->\Mat Z[2,C]:\If C=3:\Then 0\->M:M\->\Mat Z[1,5]:\IfEnd:\IfEnd
\If H=1:\Then \Do:C=4\=>99\->H
\If H\<>99:\Then \Orange \Text 50,50,"Choose probe"
\Green \Text 58,4,"Temp":\Green \Text 58,25,"Lght":\Green \Text 58,46,"Volt":\Green \Text 58,67,"Prss":\Green \Text 58,88,"Help":\Green \Text 58,109," >> ":\PxlOn 1,1
\Do:8-\Int (\Getkey/10)\->H:\LpWhile H=8
\If H=5:\Then \StoPict 1:\Cls
\Text 1,1,"HELP. Supp\orted probes are..":\Text 7,1,"Temp, temperature (\Deg>C)":\Text 13,1,"Lght, light"
\Text 19,1,"Volt, voltage (V)":\Text 25,1,"Prss, pressure (kPa)":\Text 31,1,"Mic, microphone":\Text 37,1,"C1, Custom 1":\Text 43,1,"C2, Custom 2":\Text 49,1,"C3, Custom 3"
107\->I:\Green \F-Line I,63,I,56:\Green \F-Line I,56,I+18,56:\Green \Text 58,109," OK":\PxlOn 1,1:\Do:8-\Int (\Getkey/10)\->H:\LpWhile H\<>6:\Cls:\RclPict 1:10\->H
\IfEnd
\If H=6:\Then \Green \Text 58,4,"Mic ":\Green \Text 58,25," C1 ":\Green \Text 58,46," C2 ":\Green \Text 58,67," C3 ":\Green \Text 58,88,"    ":\Green \Text 58,109," >> ":\PxlOn 1,1
\Do:8-\Int (\Getkey/10)\->H:\LpWhile H=8:H+4\->H
\IfEnd
\PxlOff 59,20:\PxlOff 60,20:\PxlOff 60,83:\PxlOff 61,83:\PxlOff 62,83:\IfEnd
\If (H>0\ And H<9)\ Or H=99:\Then \Do:H\->\Mat Z[2,C]:\Orange \Text 50,50,"Calibrate?  "
\Green \Text 58,4,"Yes ":\Green \Text 58,25,"No  ":\Green \Text 58,46,"Cstm":\Green \Text 58,67,"    ":\Green \Text 58,88,"Help":\Green \Text 58,109,"    ":\PxlOn 1,1
\Do:8-\Int (\Getkey/10)\->A:\LpWhile A=8
\If A=5:\Then \StoPict 1:\Cls
\Text 1,1,"HELP. Calibrate options:":\Text 13,1,"F1 Run calibration experiment":\Text 19,1,"F2 Use default values":\Text 25,1,"F3 Use custom conversion eqn"
107\->I:\Green \F-Line I,63,I,56:\Green \F-Line I,56,I+18,56:\Green \Text 58,109," OK":\PxlOn 1,1:\Do:8-\Int (\Getkey/10)\->A:\LpWhile A\<>6:\Cls:\RclPict 1:5\->A
\IfEnd
\LpWhile A=5
\PxlOff 60,62:\PxlOff 61,62:\PxlOff 62,62:0\->\Mat Z[5,C]
\If A=1:\Then \ClrText:" ":\Locate 1,1,"Calibrate probe...":\Locate 1,3,"1st remove all other":\Locate 1,4,"probe(s) from EA100":\Locate 8,7,"\Then press EXE":\Do:\Getkey\->W:\LpWhile W\<>31
\ClrText:" ":\Locate 1,1,"Calibration expt":" ":\Locate 1,2,"to find a,b: y=ax+b":" ":\Locate 1,3,"How many cal. points":?\->B
\Seq(0,X,1,B,1)\->\List 1:\List 1\->\List 2
{0}\->\List 6:\Send(\List 6)
{1,C,1}\->\List 6:\Send(\List 6)
{3,.3,\(-)1,0,0}\->\List 6:\Send(\List 6)
\For 1\->I \To B
\ClrText:" ":\Locate 1,1,"Point":\Locate 7,1,I:\Locate 10,1,"Wait f\or":" ":\Locate 1,2,"steady reading then":" ":\Locate 1,3,"long press EXE":" ":\Locate 1,4,"Reading="
\Do:\Receive(V):\Locate 10,4,"         ":\Locate 10,4,V:\Getkey\->W:\LpWhile W\<>31:V\->\List 1[I]:"\aster rec\orded \aster"
"Value"?\->\List 2[I]:\Next :{0}\->\List 6:\Send(\List 6)
\LinearReg \List1,\List2:\Ra\->\Mat Z[3,C]:\Rb\->\Mat Z[4,C]:1\->\Mat Z[5,C]
\ClrText:\Locate 1,2,"Using y=ax+b coeffs":\Locate 1,4,"a=":\Locate 3,4,\Ra:\Locate 1,5,"b=":\Locate 3,5,\Rb:\Locate 9,7,"EXE to cont..":\Do:\Getkey\->W:\LpWhile W\<>31:\IfEnd
\If A=2:\Then 1\->V:0\->W:\Mat Z[2,C]=4\=>223\->V:V\->\Mat Z[3,C]:W\->\Mat Z[4,C]
\IfEnd
\If A=3:\Then \ClrText:" ":" ":\Locate 1,2,"Custom conv eqn":" ":\Locate 1,3,"y=ax+b":"a"?\->\Mat Z[3,C]:"\Rb"?\->\Mat Z[4,C]:1\->\Mat Z[5,C]
\IfEnd
\If C=3:\Then \Orange \Text 50,50,"Set Trigger?":\Green \Text 58,46,"    ":\Green \Text 58,88,"    ":\PxlOn 1,1:\Do:8-\Int (\Getkey/10)\->A:\LpWhile A=8
\If A=1:\Then \ClrText:" ":\Locate 1,1,"Trigger value":?\->O:O\->\Mat Z[2,5]:" ":\Locate 1,4,"Enter 0 f\or falling":" ":\Locate 4,5,"\or 1 f\or rising":?\->U:U\<>0\=>1\->U:U\->\Mat Z[3,5]:7\->M:M\->\Mat Z[1,5]:\Else 0\->M:M\->\Mat Z[1,5]:\IfEnd
\IfEnd
\IfEnd
\LpWhile H=10
\IfEnd
3\->L:\Goto1:\Lbl 3:\IfEnd:\LpWhile C\<>6
\IfEnd
\If K=5:\Then \StoPict 1:\Cls
\Text 1,1,"HELP":\Text 7,1,"Options are..":\Text 19,1,"F1 Go: Start data-logging":\Text 25,1,"F2 Get: \Download existing data"
\Text 31,1,"F3 Setup Sampling rate, etc":\Text 37,1,"F4 Setup Probes":\Text 43,1,"F6 Exit program"
107\->I:\Green \F-Line I,63,I,56:\Green \F-Line I,56,I+18,56:\Green \Text 58,109," OK":\PxlOn 1,1:\Do:8-\Int (\Getkey/10)\->H:\LpWhile H\<>6:\Cls:\RclPict 1:\IfEnd
\LpWhile K=3\ Or K=4\ Or K=5
\LpWhile K\<>6
\Orange \Text 50,1,"EXIT! Save current settings?"
\Green \Text 58,4,"Yes ":\Green \Text 58,25,"No  ":\Green \Text 58,46,"    ":\Green \Text 58,67,"    ":\Green \Text 58,88,"    ":\Green \Text 58,109,"    ":\PxlOn 1,1
\Do:8-\Int (\Getkey/10)\->H:\LpWhile H=8
0\->\theta:\Cls
\If H=1:\Then 94054777\->\theta:\Text 1,1,"Settings data saved":\Text 7,1,"in Matrix Z":\Text 19,1,"Calculat\or RESET":\Text 25,1,"\or other use of Matrix Z":\Text 31,1,"will lose this data":\IfEnd
\Orange \Text 43,1,"(C) Charlie Watson 22:Sept:99"
107\->I:\Green \F-Line I,63,I,56:\Green \F-Line I,56,I+18,56:\Green \Text 58,4,"    ":\Green \Text 58,25,"    ":\Green \Text 58,109," OK":\PxlOn 1,1
\Do:8-\Int (\Getkey/10)\->H:\LpWhile H\<>6
\Cls
\ClrText
\Stop
\Lbl 1:\Text 19,39,"                     "
\For 1\->Z \To 4
\Mat Z[2,Z]=0\=>\Text 19,21Z+22,"-"
\Mat Z[2,Z]=1\=>\Text 19,21Z+18,"Temp"
\Mat Z[2,Z]=2\=>\Text 19,21Z+18,"Lght"
\Mat Z[2,Z]=3\=>\Text 19,21Z+18,"Volt"
\Mat Z[2,Z]=4\=>\Text 19,21Z+18,"Prss"
\Mat Z[2,Z]=5\=>\Text 19,21Z+19,"Mic"
\Mat Z[2,Z]=6\=>\Text 19,21Z+22,"C1"
\Mat Z[2,Z]=7\=>\Text 19,21Z+22,"C2"
\Mat Z[2,Z]=8\=>\Text 19,21Z+22,"C3"
\Mat Z[2,Z]=99\=>\Text 19,21Z+22,"Dist"
\If \Mat Z[2,Z]\ And \Mat Z[5,Z]:\Then \Orange \Text 8,21Z+23,"c":\Else \Orange \Text 8,21Z+23," ":\IfEnd
\Next 
\If M:\Then \Orange \Text 25,86,"T":\Else \Orange \Text 25,86," ":\IfEnd
L=3\=>\Goto3:\Lbl 8:\Text 25,40,"            ":\Text 31,40,"            ":\Text 37,40,"            ":\Text 25,40,N:\Text 31,40,T:\Text 37,40,TN
L=5\=>\Goto5:L=6\=>\Goto6:\Lbl 9:R=0\=>\Text 43,40,"Off":R=1\=>\Text 43,40,"Abs":R=2\=>\Text 43,40,"Rel":L=2\=>\Goto2:L=4\=>\Goto4:L=7\=>\Goto7:L=0\=>\Goto0

%End
%Header Record
Format:TXT
Communication SW:0
Data Type:PG
Capacity:694
File Name:GETITEM
Group Name:
Password:
Option1:
Option2:
Option3:
Option4:
%Data Record
\ClrText:\ClrList
\Locate 1,1,"Get Item v1.2":\Locate 1,2,"EA-100 must be on":\Locate 1,3,"\Then choose:"
\Locate 1,5,"F1.Single data"
\Locate 1,6,"F6.Paired data"
\Seq(0,X,1,255,1)\->\List 1
\Do:\Getkey\->P:\LpWhile P=0
\ClrText
\If P\<>29:\Then 1\->P:\Else 2\->P:\List 1\->\List 2:\IfEnd
{0}\->\List 5:\Send(\List 5)
{3,.01,\(-)1,0,0}\->\List 6:\Send(\List 6)
\Locate 1,6,"F1"
\Locate 1,7,"End"
\Locate 20,6,"F6"
\Locate 19,7,"\Log"
\Locate 4,2,"Sample:"
\Locate 5,3,"Value:"
\If P=2:\Then \Locate 5,4,"Value:":\IfEnd
0\->V
\Do
1+V\->V
\Locate 12,2,V
\For 1\->I \To P
\Locate 11,4,"        "
\Do:\Receive(D):\Locate 11,2+I,"        ":\Locate 12,2+I,D:\Getkey\->K:\LpWhile K=0
K=29\ And I=1\=>D\->\List 1[V]
K=29\ And I=2\=>D\->\List 2[V]
\If K\<>79:\Then \Locate 11,2+I,"\aster":\For 1\->J \To 200:\Getkey\->K:\Next :\IfEnd
K=79\=>\Break
\Next 
\LpWhile K\<>79
\Send(\List 5)
\Seq(\List 1[I],I,1,V,1)\->\List 1
P=2\=>\Seq(\List 2[I],I,1,V,1)\->\List 2
\List 1\DispP=2\=>\List 2\Disp\ClrText:\Locate 1,1,"Finished"
\Locate 1,2,"Again...... EXE"
\Locate 1,3,"See Data... MENU,2"
\Locate 1,4,"End........ AC\slashON"
%End
%Header Record
Format:TXT
Communication SW:0
Data Type:PG
Capacity:2788
File Name:GETPH
Group Name:
Password:
Option1:NL
Option2:
Option3:
Option4:
%Data Record
0\->A~Z:60\->N:1\->T:\(-)3.838\->A:13.72\->B:14\->G:{0}\->\List 1:{0}\->\List 2
\Do
\BG-None:\ClrText:\Cls:\ViewWindow 1,127,0,63,1,0
\Text 1,1,"GET pH"
\Text 13,1,"pH probe only in CH1":\Text 19,1,"Samples:":\Text 25,1,"Interval:":\Text 31,1,"Tot time:":\Text 37,1,"\Ymin:":\Text 43,1,"\Ymax:"
2\->L:\Goto1:\Lbl 2
\For 2\->I \To 107 \Step 21:\Green \F-Line I,63,I,56:\Green \F-Line I,56,I+18,56:\Next 
\Orange \Text 50,1,"                               "
\Green \Text 58,4," Go ":\Green \Text 58,25,"Grph":\Green \Text 58,46,"Cal ":\Green \Text 58,67,"Set ":\Green \Text 58,88,"    ":\Green \Text 58,109,"Exit ":\PxlOn 1,1
\Do:8-\Int (\Getkey/10)\->K:\LpWhile K=8
\If K=1:\Then \Orange \Text 50,1,"Wait!...":\ClrList
\Green \Text 58,4,"    ":\Green \Text 58,25,"    ":\Green \Text 58,46,"    ":\Green \Text 58,67,"    ":\Green \Text 58,88,"    ":\Green \Text 58,109,"    ":\PxlOn 1,1
\Seq(IT,I,1,N,1)\->\List 1:0\List 1\->\List 2
{0}\->\List 6:\Send(\List 6):{1,1,1}\->\List 6:\Send(\List 6):{4,1,1,0,B,A}\->\List 6:\Send(\List 6):{3,.3,\(-)1,0,1}\->\List 6:\Send(\List 6)
\Orange \Text 50,1,"F1 to start when steady":\Green \Text 58,4," Go ":\PxlOn 1,1
\Do:\Receive(V):\Text 50,100,V:8-\Int (\Getkey/10)\->I:\LpWhile I\<>1
{0}\->\List 6:\Send(\List 6):{1,1,1}\->\List 6:\Send(\List 6):{4,1,1,0,B,A}\->\List 6:\Send(\List 6)
{3,T-.27,\(-)1,0,0}\->\List 6:\Send(\List 6):\ViewWindow 1,NT,1,F,G,1:\AxesOff:\Cls:\F-Line 1,F,1,G:\F-Line D,F,NT,F:\Text 1,4,G:\Text 57,4,F:\Text 1,59,"pH"
\Receive(V):V\->\List 2[1]:\Text 1,82,"Sample 1":\PxlOn 1,1
\For 2\->I \To N:\Receive(V):\F-Line (I-1)T,\List 2[I-1],IT,V:V\->\List 2[I]:\Text 1,111,I:\PxlOn 1,1:\Next 
{0}\->\List 6:\Send(\List 6)
\Text 58,110,"[EXE]"\Disp\IfEnd
\If K=2\ And \Max(\List 1)-\Min(\List 1)\<>0\ And \Max(\List 2)-\Min(\List 2)\<>0:\Then \S-WindAuto:\AxesOn:\S-Gph2 \DrawOff:\S-Gph3 \DrawOff:\S-Gph1 \DrawOn,\xyLine,\List1,\List2,1,\Dot:\DrawStat:\Text 50,109,"[EXE]"\Disp\AxesOff
\IfEnd
\If K=4:\Then \Orange \Text 50,1,"SETUP"
\Green \Text 58,4,"Rset":\Green \Text 58,25,"Smpl":\Green \Text 58,46,"Intv":\Green \Text 58,67,"\Yscl":\Green \Text 58,109,"\Done":\PxlOn 1,1
\Do
\Do:8-\Int (\Getkey/10)\->J:\LpWhile J=8
\If J=1:\Then 60\->N:1\->T:\(-)3.838\->A:13.72\->B:0\->C:0\->F:14\->G:\IfEnd
\If J=2:\Then \ClrText:" ":\Locate 1,1,"Number of samples":" ":\Locate 1,2,"Type number, then EXE":" ":\Locate 1,3,"[2 to 255]":?\->N:N<2\=>2\->N:N>255\=>255\->N:\IfEnd
\If J=3:\Then \ClrText:" ":\Locate 1,1,"Time (seconds)":" ":\Locate 1,2,"between samples":" ":\Locate 1,3,"Type number, then EXE":" ":\Locate 1,4,"[1 to 16000]":?\->T:T<1\=>1\->T:T>16000\=>16000\->T:\IfEnd
\If J=4:\Then \ClrText:1\->D:N\->E:" ":\Locate 1,1,"\Vertical graph scl":" ":" ":\Locate 1,3,"\Ymin \-> \Ymax":"\Ymin"?\->F:"\Ymax"?\->G:\IfEnd
4\->L:J\<>6\=>\Goto1:\Lbl 4
\LpWhile J\<>6
\IfEnd
\If K=3:\Then \ClrText:" ":\Locate 1,1,"Calibrate probe...":\Locate 1,3,"1st remove all other":\Locate 1,4,"probe(s) from EA100":\Locate 8,7,"\Then press EXE":\Do:\Getkey\->W:\LpWhile W\<>31
\ClrText:" ":\Locate 1,1,"Calibration expt":" ":\Locate 1,2,"to find a,b: y=ax+b":" ":\Locate 1,3,"How many cal. points":?\->B
\Seq(0,X,1,B,1)\->\List 3:\List 3\->\List 4
{0}\->\List 6:\Send(\List 6):{1,1,1}\->\List 6:\Send(\List 6):{3,.3,\(-)1,0,0}\->\List 6:\Send(\List 6)
\For 1\->I \To B
\ClrText:" ":\Locate 1,1,"Point":\Locate 7,1,I:\Locate 10,1,"Wait f\or":" ":\Locate 1,2,"steady reading then":" ":\Locate 1,3,"long press EXE":" ":\Locate 1,4,"Reading="
\Do:\Receive(V):\Locate 10,4,"         ":\Locate 10,4,V:\Getkey\->W:\LpWhile W\<>31:V\->\List 3[I]:"\aster rec\orded \aster"
"Value"?\->\List 4[I]:\Next :{0}\->\List 6:\Send(\List 6)
\LinearReg \List3,\List4:\Ra\->A:\Rb\->B:1\->C
\ClrText:\Locate 1,2,"Using y=ax+b coeffs":\Locate 1,4,"a=":\Locate 3,4,\Ra:\Locate 1,5,"b=":\Locate 3,5,\Rb:\Locate 9,7,"EXE to cont..":\Do:\Getkey\->W:\LpWhile W\<>31
\IfEnd
\LpWhile K\<>6
\Cls:\Orange \Text 20,47,"GET pH"
\Orange \Text 33,7,"(C) Charlie Watson 16:Sept:99"
107\->I:\Green \F-Line I,63,I,56:\Green \F-Line I,56,I+18,56:\Green \Text 58,109," OK":\PxlOn 1,1
\Do:8-\Int (\Getkey/10)\->H:\LpWhile H\<>6
\Cls:\ClrText:\Stop
\Lbl 1
\If C=1:\Then \Orange \Text 7,1,"Using Calib Eqn":\Else \Orange \Text 7,1,"               ":\IfEnd
\For 19\->I \To 43 \Step 6:\Text I,40,"            ":\Next 
\Text 19,40,N:\Text 25,40,T:\Text 31,40,TN:\Text 37,40,F:\Text 43,40,G
\PxlOn 1,1:L=2\=>\Goto2:L=4\=>\Goto4

%End
%Header Record
Format:TXT
Communication SW:0
Data Type:PG
Capacity:1607
File Name:GETPULSE
Group Name:
Password:
Option1:NL
Option2:
Option3:
Option4:
%Data Record
\ClrText:\ClrList:\Locate 4,3,"Checking.."
{0}\->\List 6:\Send(\List 6)
\Norm:0\->A~Z:.03\->T:100\->N:100\->W:\(-)1\->G
\Seq(TX,X,0,N-1,1)\->\List 1
{1,1,10}\->\List 6:\Send(\List 6)
\Locate 15,3,"Ok!":\Locate 5,5,"Clip on ear":\Locate 2,7,"then EXE to start"\Disp{5,0,0,W+1,W+N}\->\List 5
{3,T,W+N,0,0}\->\List 6:\Send(\List 6)
\ClrText:\AxesOff:\Cls
\Text 1,1,"GETPULSE"
\Orange \Text 8,1,"(C) 11:Sept:1999 Charlie Watson"
\Text 15,1,"Use F1 (long press) to switch"
\Text 21,1,"current \and hist\ory views"
\Text 29,1,"Use F6 (long press) to finish"
\Text 40,1,"Please wait 15 seconds"
\Text 47,1,"Collecting initial data..":\Text 1,125," "
\S-Gph1 \DrawOn,\xyLine,\List 1,\List 2,1,\Dot,\Orange 
\S-Gph2 \DrawOn,\xyLine,\List 3,\List 4,1,\Dot,\Green 
\S-Gph3 \DrawOff
\For 0\->I \To 500:\Getkey\->K:K=29\=>\Break:\Next :K=29\=>\Goto4
\Text 54,1,"Data transfer..":\Text 1,125," "
\Do
\Send(\List 5):\Receive(\List 2):\Getkey\->K:K=29\=>\Goto3
\If K=79\ And L>1:\Then \(-)G\->G:\Cls:\IfEnd
\Send(\List 6)
\Orange \Text 56,4,"          "
\Max(\List 2)\->A:\Min(\List 2)\->B:.6A-.4B\->M
\If G=\(-)1:\Then \AxesOff:\S-WindAuto:\S-Gph2 \DrawOff:\S-Gph1 \DrawOn:\Cls:\DrawStat:\Green \F-Line \Xmin,\Ymin,\Xmin,\Ymax:\Green \F-Line \Xmin,\Ymin,\Xmax,\Ymin:\IfEnd
\Getkey\->K:K=29\=>\Goto3
\Green \Text 56,43,"Calculating..":\Text 1,125," "
1+Z\->Z:0\->P:0\->F:\(-)1\->V:1\->I:1\->R
\Do
1+I\->I
\If \List 2[I]>M:\Then \If \List 2[I]\>=\List 2[I-1]\ And \List 2[I]\>=\List 2[I+1]:\Then I\->S:1+V\->V
V=0\=>I\->C:V=1\=>I\->D:\If V\>=2:\Then (S-D)/(D-C)+(D-C)/(S-D)>2.12\=>0\->R:D\->C:S\->D:\IfEnd:F=0\=>I\->F:I+4\->I:\IfEnd:\IfEnd
\Getkey\->K:K=29\=>\Break
\LpWhile I<N-1
K=29\=>\Goto3
S-F\=>\Int (60V/(T*(S-F))+.5)\->P
P>200\=>0\->R
R=1\=>1+L\->L
L=1\ And R=1\=>[[Z\ab/c4][P]]\->\Mat Z
\If L>1:\Then \If R=1:\Then \Augment(\Mat Z,[[Z\ab/c4][P]])\->\Mat Z:\IfEnd:\Trn \Mat Z\->\Mat Z:\Mat->List\Mat Z,1)\->\List 3:\Mat->List\Mat Z,2)\->\List 4:\Trn \Mat Z\->\Mat Z:\IfEnd
\If G=1\ And L>1:\Then \AxesOn:\S-WindMan:\ViewWindow 0,(Z+10)/4,1,0,200,25:\S-Gph1 \DrawOff:\S-Gph2 \DrawOn:\Cls:\DrawStat:\Green \Text 14,4,"150":\Green \Text 45,4,"50":\Green \Text 1,4,"BPM":\IfEnd
\Getkey\->K:K=29\=>\Goto3
\Green \Text 56,43,"Pulse:        ":\Green \Text 56,68,P:\Green \Text 56,82,"bpm"
\If R=0:\Then \Orange \Text 48,44,"\asterRejected\aster":\IfEnd
\Orange \Text 1,60,"St\ored":\Text 1,87,L:\Orange \Text 1,100,"of":\Text 1,110,Z:\Orange \Text 56,99,"F6:\Stop":\Orange \Text 56,4,"F1:ChView"
A<3\=>\Orange \Text 8,8,"WARNING! EA100 batteries LOW?"
\Orange \Text 1,30,"Wait..":\Text 1,125," "
\Lbl 3
\LpWhile K\<>29\ And L<255
\Lbl 4:\Norm:\AxesOn:\ClrText:"Finished"

%End